procedure Tloginform.FormCreate(Sender: TObject);
var
  errno:integer;
  hmutex:hwnd;
begin
  hmutex:=createmutex(nil,false,pchar(application.Title));
  errno:=getlasterror;
  if errno=error_already_exists then
  begin
   application.MessageBox('  您已经打开了该软件'+#13#13+'     请不要再尝试'+#13#13+'您只能运行一个程序实例','不要试图打开多个',mb_ok);
   application.Terminate;
  end;
end;  

------------------------------------------------------------

在《Delphi 5 开发人员指南》中第13章中有一篇"防止同时出现多个应用程序实例",
代码中给出了一个MultInst.pas单元,工程引用此单元就能防止同时出现多个实例,
但实际应用中发现,如果应用程序并没有最小化,第二个实例不能把第一个实例提到最前.
下面是我改写的MultInst.pas单元,能解决这个小问题.
//==============================================================================
// Unit Name: MultInst
// Author   : ysai
// Date     : 2003-05-20
// Purpose  : 解决应用程序多实例问题
// History  :
//==============================================================================

//==============================================================================
// 工作流程
// 程序运行先取代原有向所有消息处理过程,然后广播一个消息.
// 如果有其它实例运行,收到广播消息会回发消息给发送程序,并传回它自己的句柄
// 发送程序接收到此消息,激活收到消息的程序,然后关闭自己
//==============================================================================
unit MultInst;

interface

uses
 Windows ,Messages, SysUtils, Classes, Forms;

implementation

const
 STR_UNIQUE    = '{2BE6D96E-827F-4BF9-B33E-8740412CDE96}';
 MI_ACTIVEAPP  = 1;  //激活应用程序
 MI_GETHANDLE  = 2;  //取得句柄

var
 iMessageID    : Integer;
 OldWProc      : TFNWndProc;
 MutHandle     : THandle;
 BSMRecipients : DWORD;

function NewWndProc(Handle: HWND; Msg: Integer; wParam, lParam: Longint):
 Longint; stdcall;
begin
 Result := 0;
 if Msg = iMessageID then
 begin
   case wParam of
     MI_ACTIVEAPP: //激活应用程序
       if lParam<>0 then
       begin
         //收到消息的激活前一个实例
         //为什么要在另一个程序中激活?
         //因为在同一个进程中SetForegroundWindow并不能把窗体提到最前
         if IsIconic(lParam) then
           OpenIcon(lParam)
         else
           SetForegroundWindow(lParam);
         //终止本实例
         Application.Terminate;
       end;
     MI_GETHANDLE: //取得程序句柄
       begin
         PostMessage(HWND(lParam), iMessageID, MI_ACTIVEAPP,
           Application.Handle);
       end;
   end;
 end
 else
   Result := CallWindowProc(OldWProc, Handle, Msg, wParam, lParam);
end;

procedure InitInstance;
begin
 //取代应用程序的消息处理
 OldWProc    := TFNWndProc(SetWindowLong(Application.Handle, GWL_WNDPROC,
   Longint(@NewWndProc)));

 //打开互斥对象
 MutHandle := OpenMutex(MUTEX_ALL_ACCESS, False, STR_UNIQUE);
 if MutHandle = 0 then
 begin
   //建立互斥对象
   MutHandle := CreateMutex(nil, False, STR_UNIQUE);
 end
 else begin
   Application.ShowMainForm  :=  False;
   //已经有程序实例,广播消息取得实例句柄
   BSMRecipients := BSM_APPLICATIONS;
   BroadCastSystemMessage(BSF_IGNORECURRENTTASK or BSF_POSTMESSAGE,
       @BSMRecipients, iMessageID, MI_GETHANDLE,Application.Handle);
 end;
end;

initialization
 //注册消息
 iMessageID  := RegisterWindowMessage(STR_UNIQUE);
 InitInstance;

finalization
 //还原消息处理过程
 if OldWProc <> Nil then
   SetWindowLong(Application.Handle, GWL_WNDPROC, LongInt(OldWProc));

 //关闭互斥对象
 if MutHandle <> 0 then CloseHandle(MutHandle);

end.

------------------------------------------------

Windows 下一个典型的特征就是多任务，我们可以同时打开多个窗口进行操作，也可以同时运行程序的多个实例，比如可以打开许多个资源管理器进行文件的移动复制操作。但有时出于某种考虑（比如安全性），我们要做出一些限制，让程序只能够运行一个实例。在Delphi编程中，笔者总结出了以下几种方法：
　　一、 查找窗口法
　　这是最为简单的一种方法。在程序运行前用FindWindow函数查找具有相同窗口类名和标题的窗口，如果找到了，就说明已经存在一个实例。在项目源文件的初始化部分添加以下代码：
　　Program OneApp
　　Uses
　　Forms,Windows;（这里介绍的几种方法均需在项目源文件中添加Windows单元，以后不再重复了）
　　Var Hwnd:Thandle;
　　Begin
　　 Hwnd:=FindWindow(‘TForm1’，‘SingleApp’);
　　 If Hwnd=0 then
　　 Begin
　　 Application.Initialize;
　　 Application.CreateForm(Tform1, Form1);
　　 Application.Run;
　　 End;
　　End;
　　FindWindow()函数带两个参数，FindWindow的第一个参数是类名，第二个参数是窗口标题,其中的一个参数可以忽略，但笔者强烈建议将两个参数都用上，免得凑巧别的程序也在使用相同的类名，就得不到正确的结果了。另外，如果是在Delphi IDE窗口中运行该程序，将一次都不能运行，因为已经存在相同类名和标题的窗口：设计时的窗体。
　　二、使用互斥对象
　　如果觉得查找窗口的方法效率不太高的话，可以使用创建互斥对象的方法。尽管互斥对象通常用于同步连接，但用在这个地方也是非常方便的。仅用了4句代码就轻松搞定。
　　VAR Mutex:THandle;
　　begin
　　 Mutex:=CreateMutex(NIL,True,‘SingleApp’);
　　 IF GetLastError<>ERROR_ALREADY_EXISTS THEN//如果不存在另一实例
　　 BEGIN
　　 Application.CreateHandle;
　　 Application.CreateForm (TExpNoteForm, ExpNoteForm);
　　 Application.Run;
　　 END;
　　 ReleaseMutex(Mutex);
　　end.
　　三、全局原子法
　　我们也可以利用向系统添加全局原子的方法，来防止多个程序实例的运行。全局原子由Windows 系统负责维持，它能保证其中的每个原子都是唯一的，管理其引用计数，并且当该全局原子的引用计数为0时，从内存中清除。我们用GlobalAddAtom 函数向全局原子添加一个255个字节以内的字符串，用GlobalFindAtom来检查是否已经存在该全局原子，最后在程序结束时用GlobalDeleteAtom函数删除添加的全局原子。示例如下：
　　Uses Windows
　　const iAtom=‘SingleApp’;
　　begin
　　 if GlobalFindAtom(iAtom)=0 then
　　 begin
　　 GlobalAddAtom(iAtom);
　　 Application.Initialize;
　　 Application.CreateForm(TForm1,Form1);
　　 Application.Run;
　　 GlobalDeleteAtom(GlobalFindAtom(iAtom));
　　 end
　　 else
　　 MessageBox(0,‘You can not run a second copy of this App’,‘’,mb_OK);
　　end.
　　利用全局原子的引用计数规则，我们还可以判断当前共运行了该程序的多少个实例：
　　var i:Integer;
　　begin
　　 I:=0;
　　while GlobalFindAtom(iAtom)<>0 do
　　 begin
　　 GlobalDeleteAtom(GlobalFindAtom(iAtom));
　　 i:=i＋1;
　　 end;
　　 ShowMessage(IntToStr(I));
　　end;
　　以上几种方法在笔者的Delphi 5.0，中文Windows2000下通过。